Text file
src/runtime/sys_linux_loong64.s
Documentation: runtime
1// Copyright 2022 The Go Authors. All rights reserved.
2// Use of this source code is governed by a BSD-style
3// license that can be found in the LICENSE file.
4
5//
6// System calls and other sys.stuff for loong64, Linux
7//
8
9#include "go_asm.h"
10#include "go_tls.h"
11#include "textflag.h"
12#include "cgo/abi_loong64.h"
13
14#define AT_FDCWD -100
15#define CLOCK_REALTIME 0
16#define CLOCK_MONOTONIC 1
17
18#define SYS_exit 93
19#define SYS_read 63
20#define SYS_write 64
21#define SYS_close 57
22#define SYS_getpid 172
23#define SYS_kill 129
24#define SYS_mmap 222
25#define SYS_munmap 215
26#define SYS_setitimer 103
27#define SYS_clone 220
28#define SYS_nanosleep 101
29#define SYS_sched_yield 124
30#define SYS_rt_sigreturn 139
31#define SYS_rt_sigaction 134
32#define SYS_rt_sigprocmask 135
33#define SYS_sigaltstack 132
34#define SYS_madvise 233
35#define SYS_mincore 232
36#define SYS_gettid 178
37#define SYS_futex 98
38#define SYS_sched_getaffinity 123
39#define SYS_exit_group 94
40#define SYS_tgkill 131
41#define SYS_openat 56
42#define SYS_clock_gettime 113
43#define SYS_brk 214
44#define SYS_pipe2 59
45#define SYS_timer_create 107
46#define SYS_timer_settime 110
47#define SYS_timer_delete 111
48
49// func exit(code int32)
50TEXT runtime·exit(SB),NOSPLIT|NOFRAME,$0-4
51 MOVW code+0(FP), R4
52 MOVV $SYS_exit_group, R11
53 SYSCALL
54 RET
55
56// func exitThread(wait *atomic.Uint32)
57TEXT runtime·exitThread(SB),NOSPLIT|NOFRAME,$0-8
58 MOVV wait+0(FP), R19
59 // We're done using the stack.
60 MOVW $0, R11
61 DBAR
62 MOVW R11, (R19)
63 DBAR
64 MOVW $0, R4 // exit code
65 MOVV $SYS_exit, R11
66 SYSCALL
67 JMP 0(PC)
68
69// func open(name *byte, mode, perm int32) int32
70TEXT runtime·open(SB),NOSPLIT|NOFRAME,$0-20
71 MOVW $AT_FDCWD, R4 // AT_FDCWD, so this acts like open
72 MOVV name+0(FP), R5
73 MOVW mode+8(FP), R6
74 MOVW perm+12(FP), R7
75 MOVV $SYS_openat, R11
76 SYSCALL
77 MOVW $-4096, R5
78 BGEU R5, R4, 2(PC)
79 MOVW $-1, R4
80 MOVW R4, ret+16(FP)
81 RET
82
83// func closefd(fd int32) int32
84TEXT runtime·closefd(SB),NOSPLIT|NOFRAME,$0-12
85 MOVW fd+0(FP), R4
86 MOVV $SYS_close, R11
87 SYSCALL
88 MOVW $-4096, R5
89 BGEU R5, R4, 2(PC)
90 MOVW $-1, R4
91 MOVW R4, ret+8(FP)
92 RET
93
94// func write1(fd uintptr, p unsafe.Pointer, n int32) int32
95TEXT runtime·write1(SB),NOSPLIT|NOFRAME,$0-28
96 MOVV fd+0(FP), R4
97 MOVV p+8(FP), R5
98 MOVW n+16(FP), R6
99 MOVV $SYS_write, R11
100 SYSCALL
101 MOVW R4, ret+24(FP)
102 RET
103
104// func read(fd int32, p unsafe.Pointer, n int32) int32
105TEXT runtime·read(SB),NOSPLIT|NOFRAME,$0-28
106 MOVW fd+0(FP), R4
107 MOVV p+8(FP), R5
108 MOVW n+16(FP), R6
109 MOVV $SYS_read, R11
110 SYSCALL
111 MOVW R4, ret+24(FP)
112 RET
113
114// func pipe2(flags int32) (r, w int32, errno int32)
115TEXT runtime·pipe2(SB),NOSPLIT|NOFRAME,$0-20
116 MOVV $r+8(FP), R4
117 MOVW flags+0(FP), R5
118 MOVV $SYS_pipe2, R11
119 SYSCALL
120 MOVW R4, errno+16(FP)
121 RET
122
123// func usleep(usec uint32)
124TEXT runtime·usleep(SB),NOSPLIT,$16-4
125 MOVWU usec+0(FP), R7
126 MOVV $1000, R6
127 MULVU R6, R7, R7
128 MOVV $1000000000, R6
129
130 DIVVU R6, R7, R5 // ts->tv_sec
131 REMVU R6, R7, R4 // ts->tv_nsec
132 MOVV R5, 8(R3)
133 MOVV R4, 16(R3)
134
135 // nanosleep(&ts, 0)
136 ADDV $8, R3, R4
137 MOVV R0, R5
138 MOVV $SYS_nanosleep, R11
139 SYSCALL
140 RET
141
142// func gettid() uint32
143TEXT runtime·gettid(SB),NOSPLIT,$0-4
144 MOVV $SYS_gettid, R11
145 SYSCALL
146 MOVW R4, ret+0(FP)
147 RET
148
149// func raise(sig uint32)
150TEXT runtime·raise(SB),NOSPLIT|NOFRAME,$0
151 MOVV $SYS_getpid, R11
152 SYSCALL
153 MOVW R4, R23
154 MOVV $SYS_gettid, R11
155 SYSCALL
156 MOVW R4, R5 // arg 2 tid
157 MOVW R23, R4 // arg 1 pid
158 MOVW sig+0(FP), R6 // arg 3
159 MOVV $SYS_tgkill, R11
160 SYSCALL
161 RET
162
163// func raiseproc(sig uint32)
164TEXT runtime·raiseproc(SB),NOSPLIT|NOFRAME,$0
165 MOVV $SYS_getpid, R11
166 SYSCALL
167 //MOVW R4, R4 // arg 1 pid
168 MOVW sig+0(FP), R5 // arg 2
169 MOVV $SYS_kill, R11
170 SYSCALL
171 RET
172
173// func getpid() int
174TEXT ·getpid(SB),NOSPLIT|NOFRAME,$0-8
175 MOVV $SYS_getpid, R11
176 SYSCALL
177 MOVV R4, ret+0(FP)
178 RET
179
180// func tgkill(tgid, tid, sig int)
181TEXT ·tgkill(SB),NOSPLIT|NOFRAME,$0-24
182 MOVV tgid+0(FP), R4
183 MOVV tid+8(FP), R5
184 MOVV sig+16(FP), R6
185 MOVV $SYS_tgkill, R11
186 SYSCALL
187 RET
188
189// func setitimer(mode int32, new, old *itimerval)
190TEXT runtime·setitimer(SB),NOSPLIT|NOFRAME,$0-24
191 MOVW mode+0(FP), R4
192 MOVV new+8(FP), R5
193 MOVV old+16(FP), R6
194 MOVV $SYS_setitimer, R11
195 SYSCALL
196 RET
197
198// func timer_create(clockid int32, sevp *sigevent, timerid *int32) int32
199TEXT runtime·timer_create(SB),NOSPLIT,$0-28
200 MOVW clockid+0(FP), R4
201 MOVV sevp+8(FP), R5
202 MOVV timerid+16(FP), R6
203 MOVV $SYS_timer_create, R11
204 SYSCALL
205 MOVW R4, ret+24(FP)
206 RET
207
208// func timer_settime(timerid int32, flags int32, new, old *itimerspec) int32
209TEXT runtime·timer_settime(SB),NOSPLIT,$0-28
210 MOVW timerid+0(FP), R4
211 MOVW flags+4(FP), R5
212 MOVV new+8(FP), R6
213 MOVV old+16(FP), R7
214 MOVV $SYS_timer_settime, R11
215 SYSCALL
216 MOVW R4, ret+24(FP)
217 RET
218
219// func timer_delete(timerid int32) int32
220TEXT runtime·timer_delete(SB),NOSPLIT,$0-12
221 MOVW timerid+0(FP), R4
222 MOVV $SYS_timer_delete, R11
223 SYSCALL
224 MOVW R4, ret+8(FP)
225 RET
226
227// func mincore(addr unsafe.Pointer, n uintptr, dst *byte) int32
228TEXT runtime·mincore(SB),NOSPLIT|NOFRAME,$0-28
229 MOVV addr+0(FP), R4
230 MOVV n+8(FP), R5
231 MOVV dst+16(FP), R6
232 MOVV $SYS_mincore, R11
233 SYSCALL
234 MOVW R4, ret+24(FP)
235 RET
236
237// func walltime() (sec int64, nsec int32)
238TEXT runtime·walltime(SB),NOSPLIT,$24-12
239 MOVV R3, R23 // R23 is unchanged by C code
240 MOVV R3, R25
241
242 MOVV g_m(g), R24 // R24 = m
243
244 // Set vdsoPC and vdsoSP for SIGPROF traceback.
245 // Save the old values on stack and restore them on exit,
246 // so this function is reentrant.
247 MOVV m_vdsoPC(R24), R11
248 MOVV m_vdsoSP(R24), R7
249 MOVV R11, 8(R3)
250 MOVV R7, 16(R3)
251
252 MOVV $ret-8(FP), R11 // caller's SP
253 MOVV R1, m_vdsoPC(R24)
254 MOVV R11, m_vdsoSP(R24)
255
256 MOVV m_curg(R24), R4
257 MOVV g, R5
258 BNE R4, R5, noswitch
259
260 MOVV m_g0(R24), R4
261 MOVV (g_sched+gobuf_sp)(R4), R25 // Set SP to g0 stack
262
263noswitch:
264 SUBV $16, R25
265 AND $~15, R25 // Align for C code
266 MOVV R25, R3
267
268 MOVW $CLOCK_REALTIME, R4
269 MOVV $0(R3), R5
270
271 MOVV runtime·vdsoClockgettimeSym(SB), R20
272 BEQ R20, fallback
273
274 // Store g on gsignal's stack, see sys_linux_arm64.s for detail
275 MOVBU runtime·iscgo(SB), R25
276 BNE R25, nosaveg
277
278 MOVV m_gsignal(R24), R25 // g.m.gsignal
279 BEQ R25, nosaveg
280 BEQ g, R25, nosaveg
281
282 MOVV (g_stack+stack_lo)(R25), R25 // g.m.gsignal.stack.lo
283 MOVV g, (R25)
284
285 JAL (R20)
286
287 MOVV R0, (R25)
288 JMP finish
289
290nosaveg:
291 JAL (R20)
292
293finish:
294 MOVV 0(R3), R7 // sec
295 MOVV 8(R3), R5 // nsec
296
297 MOVV R23, R3 // restore SP
298 // Restore vdsoPC, vdsoSP
299 // We don't worry about being signaled between the two stores.
300 // If we are not in a signal handler, we'll restore vdsoSP to 0,
301 // and no one will care about vdsoPC. If we are in a signal handler,
302 // we cannot receive another signal.
303 MOVV 16(R3), R25
304 MOVV R25, m_vdsoSP(R24)
305 MOVV 8(R3), R25
306 MOVV R25, m_vdsoPC(R24)
307
308 MOVV R7, sec+0(FP)
309 MOVW R5, nsec+8(FP)
310 RET
311
312fallback:
313 MOVV $SYS_clock_gettime, R11
314 SYSCALL
315 JMP finish
316
317// func nanotime1() int64
318TEXT runtime·nanotime1(SB),NOSPLIT,$16-8
319 MOVV R3, R23 // R23 is unchanged by C code
320 MOVV R3, R25
321
322 MOVV g_m(g), R24 // R24 = m
323
324 // Set vdsoPC and vdsoSP for SIGPROF traceback.
325 // Save the old values on stack and restore them on exit,
326 // so this function is reentrant.
327 MOVV m_vdsoPC(R24), R11
328 MOVV m_vdsoSP(R24), R7
329 MOVV R11, 8(R3)
330 MOVV R7, 16(R3)
331
332 MOVV $ret-8(FP), R11 // caller's SP
333 MOVV R1, m_vdsoPC(R24)
334 MOVV R11, m_vdsoSP(R24)
335
336 MOVV m_curg(R24), R4
337 MOVV g, R5
338 BNE R4, R5, noswitch
339
340 MOVV m_g0(R24), R4
341 MOVV (g_sched+gobuf_sp)(R4), R25 // Set SP to g0 stack
342
343noswitch:
344 SUBV $16, R25
345 AND $~15, R25 // Align for C code
346 MOVV R25, R3
347
348 MOVW $CLOCK_MONOTONIC, R4
349 MOVV $0(R3), R5
350
351 MOVV runtime·vdsoClockgettimeSym(SB), R20
352 BEQ R20, fallback
353
354 // Store g on gsignal's stack, see sys_linux_arm64.s for detail
355 MOVBU runtime·iscgo(SB), R25
356 BNE R25, nosaveg
357
358 MOVV m_gsignal(R24), R25 // g.m.gsignal
359 BEQ R25, nosaveg
360 BEQ g, R25, nosaveg
361
362 MOVV (g_stack+stack_lo)(R25), R25 // g.m.gsignal.stack.lo
363 MOVV g, (R25)
364
365 JAL (R20)
366
367 MOVV R0, (R25)
368 JMP finish
369
370nosaveg:
371 JAL (R20)
372
373finish:
374 MOVV 0(R3), R7 // sec
375 MOVV 8(R3), R5 // nsec
376
377 MOVV R23, R3 // restore SP
378 // Restore vdsoPC, vdsoSP
379 // We don't worry about being signaled between the two stores.
380 // If we are not in a signal handler, we'll restore vdsoSP to 0,
381 // and no one will care about vdsoPC. If we are in a signal handler,
382 // we cannot receive another signal.
383 MOVV 16(R3), R25
384 MOVV R25, m_vdsoSP(R24)
385 MOVV 8(R3), R25
386 MOVV R25, m_vdsoPC(R24)
387
388 // sec is in R7, nsec in R5
389 // return nsec in R7
390 MOVV $1000000000, R4
391 MULVU R4, R7, R7
392 ADDVU R5, R7
393 MOVV R7, ret+0(FP)
394 RET
395
396fallback:
397 MOVV $SYS_clock_gettime, R11
398 SYSCALL
399 JMP finish
400
401// func rtsigprocmask(how int32, new, old *sigset, size int32)
402TEXT runtime·rtsigprocmask(SB),NOSPLIT|NOFRAME,$0-28
403 MOVW how+0(FP), R4
404 MOVV new+8(FP), R5
405 MOVV old+16(FP), R6
406 MOVW size+24(FP), R7
407 MOVV $SYS_rt_sigprocmask, R11
408 SYSCALL
409 MOVW $-4096, R5
410 BGEU R5, R4, 2(PC)
411 MOVV R0, 0xf1(R0) // crash
412 RET
413
414// func rt_sigaction(sig uintptr, new, old *sigactiont, size uintptr) int32
415TEXT runtime·rt_sigaction(SB),NOSPLIT|NOFRAME,$0-36
416 MOVV sig+0(FP), R4
417 MOVV new+8(FP), R5
418 MOVV old+16(FP), R6
419 MOVV size+24(FP), R7
420 MOVV $SYS_rt_sigaction, R11
421 SYSCALL
422 MOVW R4, ret+32(FP)
423 RET
424
425// func sigfwd(fn uintptr, sig uint32, info *siginfo, ctx unsafe.Pointer)
426TEXT runtime·sigfwd(SB),NOSPLIT,$0-32
427 MOVW sig+8(FP), R4
428 MOVV info+16(FP), R5
429 MOVV ctx+24(FP), R6
430 MOVV fn+0(FP), R20
431 JAL (R20)
432 RET
433
434// Called from c-abi, R4: sig, R5: info, R6: cxt
435// func sigtramp(signo, ureg, ctxt unsafe.Pointer)
436TEXT runtime·sigtramp(SB),NOSPLIT|TOPFRAME,$168
437 // Save callee-save registers in the case of signal forwarding.
438 // Please refer to https://golang.org/issue/31827 .
439 SAVE_R22_TO_R31((4*8))
440 SAVE_F24_TO_F31((14*8))
441
442 // this might be called in external code context,
443 // where g is not set.
444 MOVB runtime·iscgo(SB), R7
445 BEQ R7, 2(PC)
446 JAL runtime·load_g(SB)
447
448 // R5 and R6 already contain info and ctx, respectively.
449 MOVV $runtime·sigtrampgo<ABIInternal>(SB), R7
450 JAL (R7)
451
452 // Restore callee-save registers.
453 RESTORE_R22_TO_R31((4*8))
454 RESTORE_F24_TO_F31((14*8))
455
456 RET
457
458// func cgoSigtramp()
459TEXT runtime·cgoSigtramp(SB),NOSPLIT,$0
460 JMP runtime·sigtramp(SB)
461
462// func sysMmap(addr unsafe.Pointer, n uintptr, prot, flags, fd int32, off uint32) (p unsafe.Pointer, err int)
463TEXT runtime·sysMmap(SB),NOSPLIT|NOFRAME,$0
464 MOVV addr+0(FP), R4
465 MOVV n+8(FP), R5
466 MOVW prot+16(FP), R6
467 MOVW flags+20(FP), R7
468 MOVW fd+24(FP), R8
469 MOVW off+28(FP), R9
470
471 MOVV $SYS_mmap, R11
472 SYSCALL
473 MOVW $-4096, R5
474 BGEU R5, R4, ok
475 MOVV $0, p+32(FP)
476 SUBVU R4, R0, R4
477 MOVV R4, err+40(FP)
478 RET
479ok:
480 MOVV R4, p+32(FP)
481 MOVV $0, err+40(FP)
482 RET
483
484// Call the function stored in _cgo_mmap using the GCC calling convention.
485// This must be called on the system stack.
486// func callCgoMmap(addr unsafe.Pointer, n uintptr, prot, flags, fd int32, off uint32) uintptr
487TEXT runtime·callCgoMmap(SB),NOSPLIT,$0
488 MOVV addr+0(FP), R4
489 MOVV n+8(FP), R5
490 MOVW prot+16(FP), R6
491 MOVW flags+20(FP), R7
492 MOVW fd+24(FP), R8
493 MOVW off+28(FP), R9
494 MOVV _cgo_mmap(SB), R13
495 SUBV $16, R3 // reserve 16 bytes for sp-8 where fp may be saved.
496 JAL (R13)
497 ADDV $16, R3
498 MOVV R4, ret+32(FP)
499 RET
500
501// func sysMunmap(addr unsafe.Pointer, n uintptr)
502TEXT runtime·sysMunmap(SB),NOSPLIT|NOFRAME,$0
503 MOVV addr+0(FP), R4
504 MOVV n+8(FP), R5
505 MOVV $SYS_munmap, R11
506 SYSCALL
507 MOVW $-4096, R5
508 BGEU R5, R4, 2(PC)
509 MOVV R0, 0xf3(R0) // crash
510 RET
511
512// Call the function stored in _cgo_munmap using the GCC calling convention.
513// This must be called on the system stack.
514// func callCgoMunmap(addr unsafe.Pointer, n uintptr)
515TEXT runtime·callCgoMunmap(SB),NOSPLIT,$0
516 MOVV addr+0(FP), R4
517 MOVV n+8(FP), R5
518 MOVV _cgo_munmap(SB), R13
519 SUBV $16, R3 // reserve 16 bytes for sp-8 where fp may be saved.
520 JAL (R13)
521 ADDV $16, R3
522 RET
523
524// func madvise(addr unsafe.Pointer, n uintptr, flags int32)
525TEXT runtime·madvise(SB),NOSPLIT|NOFRAME,$0
526 MOVV addr+0(FP), R4
527 MOVV n+8(FP), R5
528 MOVW flags+16(FP), R6
529 MOVV $SYS_madvise, R11
530 SYSCALL
531 MOVW R4, ret+24(FP)
532 RET
533
534// func futex(addr unsafe.Pointer, op int32, val uint32, ts, addr2 unsafe.Pointer, val3 uint32) int32
535TEXT runtime·futex(SB),NOSPLIT|NOFRAME,$0
536 MOVV addr+0(FP), R4
537 MOVW op+8(FP), R5
538 MOVW val+12(FP), R6
539 MOVV ts+16(FP), R7
540 MOVV addr2+24(FP), R8
541 MOVW val3+32(FP), R9
542 MOVV $SYS_futex, R11
543 SYSCALL
544 MOVW R4, ret+40(FP)
545 RET
546
547// int64 clone(int32 flags, void *stk, M *mp, G *gp, void (*fn)(void));
548TEXT runtime·clone(SB),NOSPLIT|NOFRAME,$0
549 MOVW flags+0(FP), R4
550 MOVV stk+8(FP), R5
551
552 // Copy mp, gp, fn off parent stack for use by child.
553 // Careful: Linux system call clobbers ???.
554 MOVV mp+16(FP), R23
555 MOVV gp+24(FP), R24
556 MOVV fn+32(FP), R25
557
558 MOVV R23, -8(R5)
559 MOVV R24, -16(R5)
560 MOVV R25, -24(R5)
561 MOVV $1234, R23
562 MOVV R23, -32(R5)
563
564 MOVV $SYS_clone, R11
565 SYSCALL
566
567 // In parent, return.
568 BEQ R4, 3(PC)
569 MOVW R4, ret+40(FP)
570 RET
571
572 // In child, on new stack.
573 MOVV -32(R3), R23
574 MOVV $1234, R19
575 BEQ R23, R19, 2(PC)
576 MOVV R0, 0(R0)
577
578 // Initialize m->procid to Linux tid
579 MOVV $SYS_gettid, R11
580 SYSCALL
581
582 MOVV -24(R3), R25 // fn
583 MOVV -16(R3), R24 // g
584 MOVV -8(R3), R23 // m
585
586 BEQ R23, nog
587 BEQ R24, nog
588
589 MOVV R4, m_procid(R23)
590
591 // TODO: setup TLS.
592
593 // In child, set up new stack
594 MOVV R23, g_m(R24)
595 MOVV R24, g
596 //CALL runtime·stackcheck(SB)
597
598nog:
599 // Call fn
600 JAL (R25)
601
602 // It shouldn't return. If it does, exit that thread.
603 MOVW $111, R4
604 MOVV $SYS_exit, R11
605 SYSCALL
606 JMP -3(PC) // keep exiting
607
608// func sigaltstack(new, old *stackt)
609TEXT runtime·sigaltstack(SB),NOSPLIT|NOFRAME,$0
610 MOVV new+0(FP), R4
611 MOVV old+8(FP), R5
612 MOVV $SYS_sigaltstack, R11
613 SYSCALL
614 MOVW $-4096, R5
615 BGEU R5, R4, 2(PC)
616 MOVV R0, 0xf1(R0) // crash
617 RET
618
619// func osyield()
620TEXT runtime·osyield(SB),NOSPLIT|NOFRAME,$0
621 MOVV $SYS_sched_yield, R11
622 SYSCALL
623 RET
624
625// func sched_getaffinity(pid, len uintptr, buf *uintptr) int32
626TEXT runtime·sched_getaffinity(SB),NOSPLIT|NOFRAME,$0
627 MOVV pid+0(FP), R4
628 MOVV len+8(FP), R5
629 MOVV buf+16(FP), R6
630 MOVV $SYS_sched_getaffinity, R11
631 SYSCALL
632 MOVW R4, ret+24(FP)
633 RET
634
635// func sbrk0() uintptr
636TEXT runtime·sbrk0(SB),NOSPLIT|NOFRAME,$0-8
637 // Implemented as brk(NULL).
638 MOVV $0, R4
639 MOVV $SYS_brk, R11
640 SYSCALL
641 MOVV R4, ret+0(FP)
642 RET
643
644TEXT runtime·access(SB),$0-20
645 MOVV R0, 2(R0) // unimplemented, only needed for android; declared in stubs_linux.go
646 MOVW R0, ret+16(FP) // for vet
647 RET
648
649TEXT runtime·connect(SB),$0-28
650 MOVV R0, 2(R0) // unimplemented, only needed for android; declared in stubs_linux.go
651 MOVW R0, ret+24(FP) // for vet
652 RET
653
654TEXT runtime·socket(SB),$0-20
655 MOVV R0, 2(R0) // unimplemented, only needed for android; declared in stubs_linux.go
656 MOVW R0, ret+16(FP) // for vet
657 RET
658
659// func vgetrandom1(buf *byte, length uintptr, flags uint32, state uintptr, stateSize uintptr) int
660TEXT runtime·vgetrandom1<ABIInternal>(SB),NOSPLIT,$16-48
661 MOVV R3, R23
662
663 MOVV runtime·vdsoGetrandomSym(SB), R12
664
665 MOVV g_m(g), R24
666
667 MOVV m_vdsoPC(R24), R13
668 MOVV R13, 8(R3)
669 MOVV m_vdsoSP(R24), R13
670 MOVV R13, 16(R3)
671 MOVV R1, m_vdsoPC(R24)
672 MOVV $buf-8(FP), R13
673 MOVV R13, m_vdsoSP(R24)
674
675 AND $~15, R3
676
677 MOVBU runtime·iscgo(SB), R13
678 BNE R13, nosaveg
679 MOVV m_gsignal(R24), R13
680 BEQ R13, nosaveg
681 BEQ g, R13, nosaveg
682 MOVV (g_stack+stack_lo)(R13), R25
683 MOVV g, (R25)
684
685 JAL (R12)
686
687 MOVV R0, (R25)
688 JMP restore
689
690nosaveg:
691 JAL (R12)
692
693restore:
694 MOVV R23, R3
695 MOVV 16(R3), R25
696 MOVV R25, m_vdsoSP(R24)
697 MOVV 8(R3), R25
698 MOVV R25, m_vdsoPC(R24)
699 NOP R4 // Satisfy go vet, since the return value comes from the vDSO function.
700 RET
View as plain text